From be21a44dd2c96b3432cc00bad54b8dd4badb14ef Mon Sep 17 00:00:00 2001
From: Kimmo Varis <kimmov@gmail.com>
Date: Mon, 11 Jun 2012 14:37:51 +0300
Subject: [PATCH] Tools: Adding a tools.pro to build dmake.

---
 tools/tools.pro | 40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 tools/tools.pro

diff --git a/tools/tools.pro b/tools/tools.pro
new file mode 100644
index 000000000..dc1d69a4e
--- /dev/null
+++ b/tools/tools.pro
@@ -0,0 +1,40 @@
+TEMPLATE = app
+TARGET = dmake
+DEPENDPATH += .
+INCLUDEPATH += . ../lib
+OBJECTS_DIR = temp
+CONFIG += warn_on
+CONFIG -= qt app_bundle
+
+SOURCES += dmake.cpp \
+           ../cli/filelister.cpp \
+           ../lib/path.cpp
+
+HEADERS += ../cli/filelister.h \
+           ../lib/path.h
+
+CONFIG(release, debug|release) {
+	DEFINES += NDEBUG
+}
+
+win32 {
+    CONFIG += embed_manifest_exe console
+    DEFINES += _CRT_SECURE_NO_WARNINGS
+    LIBS += -lshlwapi
+}
+
+# Add more strict compiling flags for GCC
+contains(QMAKE_CXX, g++) {
+    QMAKE_CXXFLAGS_WARN_ON += -Wextra -pedantic -Wfloat-equal -Wcast-qual -Wlogical-op -Wno-long-long
+
+    CONFIG(debug, debug|release) {
+        # checked STL
+        DEFINES += _GLIBCXX_DEBUG
+    }
+}
+
+# Change Visual Studio compiler (CL) warning level to W4
+contains(QMAKE_CXX, cl) {
+    QMAKE_CXXFLAGS_WARN_ON -= -W3
+    QMAKE_CXXFLAGS_WARN_ON += -W4
+}