TEMPLATE = app
TARGET = gui
QT += xml
CONFIG += warn_on
DEPENDPATH += .
INCLUDEPATH += .

DESTDIR = .
RCC_DIR = temp
MOC_DIR = temp
OBJECTS_DIR = temp
UI_DIR = temp

win32 {
   DESTDIR = ..\Build\gui
   RCC_DIR = ..\BuildTmp\gui
   MOC_DIR = ..\BuildTmp\gui
   OBJECTS_DIR = ..\BuildTmp\gui
   UI_DIR = ..\BuildTmp\gui
}

RESOURCES = gui.qrc
FORMS = main.ui \
    resultsview.ui \
    application.ui \
    settings.ui \
    file.ui \
    projectfile.ui \
    about.ui

TRANSLATIONS =  cppcheck_fi.ts \
                cppcheck_nl.ts \
                cppcheck_en.ts \
                cppcheck_se.ts \
                cppcheck_de.ts \
                cppcheck_pl.ts \
                cppcheck_ru.ts 

# Windows-specific options
CONFIG += embed_manifest_exe

include($$PWD/../lib/lib.pri)
HEADERS += mainwindow.h \
           checkthread.h \
           resultsview.h \
           resultstree.h \
           settingsdialog.h \
           threadresult.h \
           threadhandler.h \
           applicationlist.h \
           applicationdialog.h \
           aboutdialog.h \
           common.h \
           fileviewdialog.h \
           projectfile.h \
           projectfiledialog.h \
           report.h \
           txtreport.h \
           xmlreport.h \
           translationhandler.h \
           csvreport.h
SOURCES += main.cpp \
           mainwindow.cpp\
           checkthread.cpp \
           resultsview.cpp \
           resultstree.cpp \
           threadresult.cpp \
           threadhandler.cpp \
           settingsdialog.cpp \
           applicationlist.cpp \
           applicationdialog.cpp \
           aboutdialog.cpp \
           fileviewdialog.cpp \
           projectfile.cpp \
           projectfiledialog.cpp \
           report.cpp \
           txtreport.cpp \
           xmlreport.cpp \
           translationhandler.cpp \
           csvreport.cpp

win32 {
    RC_FILE = cppcheck-gui.rc
    HEADERS += ../cli/resource.h
    LIBS += -lshlwapi -lhtmlhelp
}

# run lrelease before build
lrelease.commands = lrelease gui.pro
QMAKE_EXTRA_TARGETS += lrelease
PRE_TARGETDEPS += lrelease